home *** CD-ROM | disk | FTP | other *** search
/ TOS Silver 2000 / TOS Silver 2000.iso / Anwendun / Pov / POVTOOLS / SCENES / LEVEL3 / CHESS.POV next >
Encoding:
Text File  |  1995-11-25  |  15.1 KB  |  726 lines
  1. // Persistence Of Vision raytracer version 2.0 sample file.
  2.  
  3. // By Ville Saari
  4. // Copyright (c) 1991 Ferry Island Pixelboys
  5.  
  6. /*
  7. *
  8. * POV-Ray scene description for chess board.
  9. * 
  10. * Created: 01-Feb-91
  11. * Updated: 02-Mar-91
  12. *
  13. * This scene has 430 primitives in objects and 41 in bounding shapes and
  14. * it takes over 40 hours to render by standard amiga.
  15. *
  16. * If you do some nice modifications or additions to this file, please send 
  17. * me a copy. My Internet address is:
  18. *
  19. *         vsaari@niksula.hut.fi
  20. */
  21.  
  22. #include "shapes.inc"
  23. #include "colors.inc"
  24. #include "textures.inc"
  25.  
  26. camera {
  27.    location <59, 20, -48>
  28.    direction <0, 0, 1>
  29.    up <0, 1, 0>
  30.    right <4/3, 0, 0>
  31.    look_at <0, 0, 1>
  32. }
  33.  
  34. light_source { <800, 600, -200> colour White }
  35.  
  36. #declare Pawn = union {
  37.    sphere { <0, 7, 0>, 1.5 }
  38.  
  39.    sphere { <0, 0, 0>, 1 
  40.       scale <1.2, 0.3, 1.2>
  41.       translate 5.5*y
  42.    }
  43.  
  44.    intersection {
  45.       plane { y, 5.5 }
  46.       object {
  47.          Hyperboloid_Y
  48.          translate 5*y
  49.          scale <0.5, 1, 0.5>
  50.       }
  51.       plane { -y, -2.5 }
  52.    }
  53.  
  54.    sphere { <0, 0, 0>, 1 
  55.       scale <2, 0.5, 2>
  56.       translate <0, 2.3, 0>
  57.    }
  58.  
  59.    intersection {
  60.       sphere { <0, 0, 0>, 2.5 }
  61.       plane { -y, 0 }
  62.    }
  63. }
  64.  
  65. #declare Rook = union {
  66.    intersection {
  67.       union {
  68.          plane { +x, -0.5 }
  69.          plane { -x, -0.5 }
  70.          plane { y, 9 }
  71.       }
  72.  
  73.       union {
  74.          plane { +z, -0.5 }
  75.          plane { -z, -0.5 }
  76.          plane { y, 9 }
  77.       }
  78.  
  79.       plane { y, 10 }
  80.       object { Cylinder_Y scale <2, 1, 2> }
  81.       object { Cylinder_Y scale <1.2, 1, 1.2> inverse }
  82.       plane { -y, -8 }
  83.    }
  84.  
  85.    intersection {
  86.       plane { y, 8 }
  87.       object { Hyperboloid_Y
  88.          scale <1, 1.5, 1>
  89.          translate 5.401924*y
  90.       }
  91.       plane { -y, -3 }
  92.    }
  93.  
  94.    sphere { <0, 0, 0>, 1 
  95.       scale <2.5, 0.5, 2.5>
  96.       translate 2.8*y
  97.    }
  98.  
  99.    intersection {
  100.       sphere { <0, 0, 0>, 3 }
  101.       plane { -y, 0 }
  102.    }
  103. }
  104.  
  105. #declare Knight = union {
  106.    intersection {
  107.       object { Cylinder_Z
  108.          scale <17.875, 17.875, 1>
  109.          translate <-18.625, 7, 0>
  110.          inverse
  111.       }
  112.  
  113.       object { Cylinder_Z
  114.          scale <17.875, 17.875, 1>
  115.          translate <18.625, 7, 0>
  116.          inverse
  117.       }
  118.  
  119.       object { Cylinder_X
  120.          scale <1, 5.1, 5.1>
  121.          translate <0, 11.2, -5>
  122.          inverse
  123.       }
  124.  
  125.       union {
  126.          plane { y, 0
  127.             rotate 30*x
  128.             translate 9.15*y
  129.          }
  130.          plane { z, 0
  131.             rotate -20*x
  132.             translate 10*y
  133.          }
  134.       }
  135.  
  136.       union {
  137.          plane { -y, 0
  138.             rotate 30*x
  139.             translate 7.15*y
  140.          }
  141.          plane { y, 0
  142.             rotate 60*x
  143.             translate 7.3*y
  144.          }
  145.       }
  146.  
  147.       union {
  148.          plane { y, 0
  149.             rotate -45*y
  150.          }
  151.          plane { y, 0
  152.             rotate 45*z
  153.          }
  154.          translate 9*y
  155.       }
  156.  
  157.       object { Cylinder_Y scale <2, 1, 2> }
  158.       sphere { <0, 7, 0>, 4 }
  159.    }
  160.  
  161.    sphere { <0, 0, 0>, 1 
  162.       scale <2.5, 0.5, 2.5>
  163.       translate <0, 2.8, 0>
  164.    }
  165.  
  166.    intersection {
  167.       sphere { <0, 0, 0>, 3 }
  168.       plane { -y, 0 }
  169.    }
  170. }
  171.  
  172. #declare Bishop = union {
  173.    sphere { <0, 10.8, 0>, 0.4 }
  174.  
  175.    intersection {
  176.       union {
  177.          plane { -z, -0.25 }
  178.          plane { +z, -0.25 }
  179.          plane { y, 0  }
  180.          rotate 30*x
  181.          translate 8.5*y
  182.       }
  183.  
  184.       sphere { <0, 0, 0>, 1 
  185.          scale <1.4, 2.1, 1.4>
  186.          translate 8.4*y
  187.       }
  188.  
  189.       plane { -y, -7 }
  190.    }
  191.  
  192.    sphere { <0, 0, 0>, 1 
  193.       scale <1.5, 0.4, 1.5>
  194.       translate 7*y
  195.    }
  196.  
  197.    intersection {
  198.       plane { y, 7 }
  199.       object {
  200.          Hyperboloid_Y
  201.          scale <0.6, 1.4, 0.6>
  202.          translate 7*y
  203.       }
  204.       plane { -y, -3 }
  205.    }
  206.  
  207.    sphere { <0, 0, 0>, 1 
  208.       scale <2.5, 0.5, 2.5>
  209.       translate 2.8*y
  210.    }
  211.  
  212.    intersection {
  213.       sphere { <0, 0, 0>, 3 }
  214.       plane { -y, 0 }
  215.    }
  216. }
  217.  
  218. #declare QueenAndKing = union {
  219.    sphere { <0, 10.5, 0>, 1.5 }
  220.  
  221.    intersection {
  222.       union {
  223.          sphere { <1.75, 12, 0>, 0.9  rotate 150*y }
  224.          sphere { <1.75, 12, 0>, 0.9  rotate 120*y }
  225.          sphere { <1.75, 12, 0>, 0.9  rotate 90*y }
  226.          sphere { <1.75, 12, 0>, 0.9  rotate 60*y }
  227.          sphere { <1.75, 12, 0>, 0.9  rotate 30*y }
  228.          sphere { <1.75, 12, 0>, 0.9  }
  229.          sphere { <1.75, 12, 0>, 0.9  rotate -30*y }
  230.          sphere { <1.75, 12, 0>, 0.9  rotate -60*y }
  231.          sphere { <1.75, 12, 0>, 0.9  rotate -90*y }
  232.          sphere { <1.75, 12, 0>, 0.9  rotate -120*y }
  233.          sphere { <1.75, 12, 0>, 0.9  rotate -150*y }
  234.          sphere { <1.75, 12, 0>, 0.9  rotate  180*y }
  235.          inverse
  236.       }
  237.  
  238.       plane { y, 11.5 }
  239.  
  240.       object { QCone_Y
  241.          scale <1, 3, 1>
  242.          translate 5*y
  243.       }
  244.  
  245.       plane { -y, -8 }
  246.    }
  247.  
  248.    sphere { <0, 0, 0>, 1
  249.       scale <1.8, 0.4, 1.8>
  250.       translate 8*y
  251.    }
  252.  
  253.    intersection {
  254.       plane { y, 8 }
  255.       object { Hyperboloid_Y
  256.          scale <0.7, 1.6, 0.7>
  257.          translate 7*y
  258.       }
  259.       plane { -y, -3 }
  260.    }
  261.  
  262.    sphere { <0, 0, 0>, 1 
  263.       scale <2.5, 0.5, 2.5>
  264.       translate 2.8*y
  265.    }
  266.  
  267.    intersection {
  268.       sphere { <0, 0, 0>, 3 }
  269.       plane { <0, -1, 0>, 0 }
  270.    }
  271. }
  272.  
  273. #declare Queen = union {
  274.    sphere { <0, 12.3, 0>, 0.4 }
  275.    object { QueenAndKing }
  276. }
  277.  
  278. #declare King = union {
  279.    intersection {
  280.       union {
  281.          intersection {
  282.             plane { y, 13 }
  283.             plane { -y, -12.5 }
  284.          }
  285.  
  286.          intersection {
  287.             plane { +x, 0.25 }
  288.             plane { -x, 0.25 }
  289.          }
  290.       }
  291.  
  292.       plane { +z,  0.25 }
  293.       plane { -z,  0.25 }
  294.       plane { +x,  0.75 }
  295.       plane { -x,  0.75 }
  296.       plane { +y,  13.5  }
  297.       plane { -y,  -11.5  }
  298.    }
  299.  
  300.    object { QueenAndKing }
  301. }
  302.  
  303. #declare WWood = texture {
  304.    pigment {
  305.       wood
  306.       turbulence 0.1
  307.       colour_map {
  308.          [ 0.0 0.35 colour red 0.7  green 0.4
  309.                     colour red 0.7  green 0.4  ]
  310.          [ 0.35 1.0 colour red 0.95 green 0.62
  311.                     colour red 0.95 green 0.62 ]
  312.       }
  313.       scale <0.6, 1000.0, 0.6>
  314.       translate <200.0, 0.0, 100.0>
  315.    }
  316.    finish {
  317.       specular 1
  318.       roughness 0.02
  319.    }
  320. }
  321.  
  322. #declare BWood = texture {
  323.    pigment {
  324.       wood
  325.       turbulence 0.1
  326.       colour_map {
  327.          [ 0.0 0.55 colour red 0.45 green 0.25
  328.          colour red 0.45 green 0.25 ]
  329.          [ 0.55 1.0 colour red 0.30 green 0.16
  330.          colour red 0.30 green 0.16 ]
  331.       }
  332.       scale <0.6, 1000.0, 0.6>
  333.       translate <100.0, 0.0, -200.0>
  334.    }
  335.    finish {
  336.       specular 1
  337.       roughness 0.02
  338.    }
  339. }
  340.  
  341. #declare WPawn = object {
  342.    Pawn
  343.  
  344.    bounded_by { sphere { <0, 4, 0>, 4.72 } }
  345.  
  346.    texture {
  347.       WWood
  348.       pigment { quick_color red 0.95 green 0.62 }
  349.    }
  350. }
  351.  
  352. #declare BPawn = object {
  353.    Pawn
  354.  
  355.    bounded_by { sphere { <0, 4, 0>, 4.72 } }
  356.  
  357.    texture {
  358.       BWood
  359.       pigment { quick_color red 0.4 green 0.2 }
  360.    }
  361. }
  362.  
  363. #declare WRook = object {
  364.    Rook
  365.  
  366.    bounded_by { sphere { <0, 5, 0>, 5.831 } }
  367.  
  368.    texture {
  369.       WWood
  370.       pigment { quick_color red 0.95 green 0.62 }
  371.    }
  372. }
  373.  
  374. #declare BRook = object {
  375.    Rook
  376.  
  377.    bounded_by { sphere { <0, 5, 0>, 5.831 } }
  378.  
  379.    texture {
  380.       BWood
  381.       pigment { quick_color red 0.4 green 0.2 }
  382.    }
  383. }
  384.  
  385. #declare WKnight = object {
  386.    Knight
  387.  
  388.    bounded_by { sphere { <0, 5, 0>, 5.831 } }
  389.  
  390.    texture {
  391.       WWood
  392.       pigment { quick_color red 0.95 green 0.62 }
  393.    }
  394. }
  395.  
  396. #declare BKnight = object {
  397.    Knight
  398.    rotate 180*y
  399.  
  400.    bounded_by { sphere { <0, 5, 0>, 5.831 } }
  401.  
  402.    texture { 
  403.       BWood
  404.       pigment { quick_color red 0.4 green 0.2 }
  405.    }
  406. }
  407.  
  408. #declare WBishop = object {
  409.    Bishop
  410.  
  411.    bounded_by { sphere { <0, 5.5, 0>, 6.265 } }
  412.  
  413.    texture {
  414.       WWood
  415.       pigment { quick_color red 0.95 green 0.62 }
  416.    }
  417. }
  418.  
  419. #declare BBishop = object {
  420.    Bishop
  421.    rotate 180*y
  422.  
  423.    bounded_by { sphere { <0, 5.5 ,0>, 6.265 } }
  424.  
  425.    texture {
  426.       BWood
  427.       pigment { quick_color red 0.4 green 0.2 }
  428.    }
  429. }
  430.  
  431. #declare WQueen = object {
  432.    Queen
  433.  
  434.    bounded_by {
  435.       intersection {
  436.          sphere { <0, 6, 0>, 6.71 }
  437.          object { Cylinder_Y scale <3, 1, 3> }
  438.       }
  439.    }
  440.  
  441.    texture {
  442.       WWood
  443.       pigment { quick_color red 0.95 green 0.62 }
  444.    }
  445. }
  446.  
  447. #declare BQueen = object {
  448.    Queen
  449.  
  450.    bounded_by {
  451.       intersection {
  452.          sphere { <0, 6, 0>, 6.71 }
  453.          object { Cylinder_Y scale <3, 1, 3> }
  454.       }
  455.    }
  456.  
  457.    texture {
  458.       BWood
  459.       pigment { quick_color red 0.4 green 0.2 }
  460.    }
  461. }
  462.  
  463. #declare WKing = object {
  464.    King
  465.  
  466.    bounded_by {
  467.       intersection {
  468.          sphere { <0, 6.5, 0>, 7.16 }
  469.          object { Cylinder_Y scale <3, 1, 3> }
  470.       }
  471.    }
  472.  
  473.    texture {
  474.       WWood
  475.       pigment { quick_color red 0.95 green 0.62 }
  476.    }
  477. }
  478.  
  479. #declare BKing = object {
  480.    King
  481.  
  482.    bounded_by {
  483.       intersection {
  484.          sphere { <0, 6.5, 0>, 7.16 }
  485.          object { Cylinder_Y scale <3, 1, 3> }
  486.       }
  487.    }
  488.  
  489.    texture {
  490.       BWood
  491.       pigment { quick_color red 0.4 green 0.2 }
  492.    }
  493. }
  494.  
  495. /* Sky */
  496. sphere { <0, -39000, 0>, 40000
  497.    inverse
  498.  
  499.    pigment {
  500.       bozo
  501.       turbulence 0.6
  502.       colour_map {
  503.          [0 0.5 colour red 0.4 green 0.5 blue 1
  504.                 colour red 0.4 green 0.5 blue 1.0]
  505.          [0.5 0.7 colour red 0.4 green 0.5 blue 1
  506.                   colour red 1 green 1 blue 1.0]
  507.          [0.7 1 colour red 1 green 1 blue 1
  508.                 colour red 0.7 green 0.7 blue 0.7]
  509.       }
  510.       scale 500
  511.       quick_color red 0.4 green 0.5 blue 1
  512.    }
  513.    finish {
  514.       ambient 1
  515.       diffuse 0
  516.    }
  517. }
  518.  
  519. /* Ground */
  520. plane { y, -80
  521.    pigment { Green }
  522.    finish {
  523.       crand 0.05
  524.       ambient 0.5
  525.       diffuse 0.5
  526.    }
  527. }
  528.  
  529. #declare Frame = intersection {
  530.    plane { +y, -0.0001 }
  531.    plane { -y, 3 }
  532.    plane { -z, 35 }
  533.    plane { <-1, 0, 1>, 0 }
  534.    plane { < 1, 0, 1>, 0 }
  535. }
  536.  
  537. union {
  538.    union {
  539.       object {
  540.          union {
  541.             object { Frame }
  542.             object { Frame rotate 180*y }
  543.          }
  544.  
  545.          pigment {
  546.             wood
  547.             turbulence 0.3
  548.             scale <0.8, 1000, 0.8>
  549.             rotate -88*z
  550.             translate <200, 40, -20>
  551.             quick_color red 0.5 green 0.25
  552.          }
  553.          finish {
  554.             specular 1
  555.             roughness 0.02
  556.          }
  557.       } // object
  558.  
  559.       object {
  560.          union {
  561.             object { Frame rotate -90*y }
  562.             object { Frame rotate  90*y }
  563.          }
  564.  
  565.          pigment {
  566.             wood
  567.             turbulence 0.3
  568.             scale <0.8, 1000, 0.8>
  569.             rotate -91*x
  570.             translate <100, 30, 0>
  571.             quick_color red 0.5 green 0.25
  572.          }
  573.          finish {
  574.             specular 1
  575.             roughness 0.02
  576.          }
  577.       } // object
  578.  
  579.       /* Board */
  580.       intersection {
  581.          plane { +x, 32 }
  582.          plane { -x, 32 }
  583.          plane { +y, 0 }
  584.          plane { -y, 1 }
  585.          plane { +z, 32 }
  586.          plane { -z, 32 }
  587.  
  588.          texture {
  589.             tiles {
  590.                texture {
  591.                   pigment {
  592.                      marble
  593.                      turbulence 1.0
  594.                      colour_map {
  595.                         [0.0 0.7 colour White
  596.                                  colour White]
  597.                         [0.7 0.9 colour White
  598.                                  colour red 0.8 green 0.8 blue 0.8]
  599.                         [0.9 1.0 colour red 0.8 green 0.8 blue 0.8
  600.                                  colour red 0.5 green 0.5 blue 0.5]
  601.                      }
  602.                      scale <0.6, 1, 0.6>
  603.                      rotate -30*y
  604.                   }
  605.                   finish {
  606.                      specular 1
  607.                      roughness 0.02
  608.                      reflection 0.25
  609.                   }
  610.                } // texture
  611.                tile2
  612.                texture {
  613.                   pigment {
  614.                      granite
  615.                      scale <0.3, 1, 0.3>
  616.                      colour_map {
  617.                         [0 1 colour Black
  618.                              colour red 0.5 green 0.5 blue 0.5]
  619.                      }
  620.                   }
  621.                   finish {
  622.                      specular 1
  623.                      roughness 0.02
  624.                      reflection 0.25
  625.                   }
  626.                }
  627.             } // texture
  628.             scale <8, 1, 8>
  629.          } //texture
  630.       } // intersection
  631.  
  632.       /* Table */
  633.       union {
  634.          intersection {
  635.             plane { +y, -3 }
  636.             plane { -y,  8 }
  637.             sphere { <0, -5.5, 0>, 55 }
  638.          }
  639.  
  640.          intersection {
  641.             plane { y, -8 }
  642.             object {
  643.                Hyperboloid_Y
  644.                scale <10, 20, 10>
  645.                translate -20*y
  646.             }
  647.          }
  648.  
  649.          pigment {
  650.             granite
  651.             scale 6
  652.          }
  653.          finish {
  654.             specular 1
  655.             roughness 0.02
  656.             reflection 0.3
  657.          }
  658.       } // union
  659.  
  660.       bounded_by { plane { y, 0 } }
  661.    }
  662.  
  663.    union {
  664.       object { WPawn translate <-28, 0, -20> }
  665.       object { WPawn translate <-20, 0, -20> }
  666.       object { WPawn translate <-12, 0, -20> }
  667.       object { WPawn translate < -4, 0, -20> }
  668.       object { WPawn translate <  4, 0, -20> }
  669.       object { WPawn translate < 12, 0, -20> }
  670.       object { WPawn translate < 20, 0, -20> }
  671.       object { WPawn translate < 28, 0, -20> }
  672.  
  673.       object { WRook   translate <-28, 0, -28> }
  674.       object { WKnight translate <-20, 0, -28> }
  675.       object { WBishop translate <-12, 0, -28> }
  676.       object { WQueen  translate < -4, 0, -28> }
  677.       object { WKing   translate <  4, 0, -28> }
  678.       object { WBishop translate < 12, 0, -28> }
  679.       object { WKnight translate < 20, 0, -28> }
  680.       object { WRook   translate < 28, 0, -28> }
  681.  
  682.       bounded_by {
  683.          object {
  684.             Cylinder_X
  685.             scale <1, 9.56, 9.56>
  686.             translate <0, 6.5, -24>
  687.          }
  688.       }
  689.    }
  690.  
  691.    union {
  692.       object { BPawn translate <-28, 0, 20> }
  693.       object { BPawn translate <-20, 0, 20> }
  694.       object { BPawn translate <-12, 0, 20> }
  695.       object { BPawn translate < -4, 0, 20> }
  696.       object { BPawn translate <  4, 0, 20> }
  697.       object { BPawn translate < 12, 0, 20> }
  698.       object { BPawn translate < 20, 0, 20> }
  699.       object { BPawn translate < 28, 0, 20> }
  700.  
  701.       object { BRook   translate <-28, 0, 28> }
  702.       object { BKnight translate <-20, 0, 28> }
  703.       object { BBishop translate <-12, 0, 28> }
  704.       object { BQueen  translate < -4, 0, 28> }
  705.       object { BKing   translate <  4, 0, 28> }
  706.       object { BBishop translate < 12, 0, 28> }
  707.       object { BKnight translate < 20, 0, 28> }
  708.       object { BRook   translate < 28, 0, 28> }
  709.  
  710.       bounded_by {
  711.          object {
  712.             Cylinder_X
  713.             scale <1, 9.56, 9.56>
  714.             translate <0, 6.5, 24>
  715.          }
  716.       }
  717.    }
  718.  
  719.    bounded_by {
  720.       intersection {
  721.          plane { y, 13.5 }
  722.          sphere { -30*y, 63 }
  723.       }
  724.    }
  725. }
  726.